%option c++
%option noyywrap
%option prefix="stm"

%{
#include "graphloader.h"

int yywrap(){return 0;}

int pushed_state;
%}


%s COMMENT

%s ADD_PROCESSORS
%s AWAIT_PROCESSOR_SEPARATOR
%s AWAIT_PROCESSOR_NAME

%s ADD_DEPENDENCIES
%s AWAIT_DEPENDENCY_SEPARATOR
%s AWAIT_DEPENDENCY_SLOT
%s AWAIT_DEPENDENCY_LINK
%s AWAIT_DEPENDENCY_SOURCE

%s SET_PARAMETERS
%s AWAIT_PARAMETER_SEPARATOR
%s AWAIT_PARAMETER_NAME
%s AWAIT_PARAMETER_EQUALS
%s AWAIT_PARAMETER_VALUE

%s AWAIT_OUTPUT

EOL            [\n]
whitespace     [ \t]*
comment        #

string         [\"][a-z0-9_ \t]*[\"]
float          [-]?[0-9]+\.[0-9]*
chromaticity   <[ \t]*{float},[ \t]*{float}[ \t]*>
integer        [-]?[0-9]+
true           [Tt][Rr][Uu][Ee]
false          [Ff][Aa][Ll][Ss][Ee]

separator      [:]
equals         [=]
link           [<][-]

%%
{whitespace}

<<EOF>> {return graphloader::END;}
<INITIAL,ADD_PROCESSORS,ADD_DEPENDENCIES,SET_PARAMETERS>{EOL} {}

<COMMENT>{EOL} {
    BEGIN pushed_state;
    }

<INITIAL>{comment} {
    pushed_state = INITIAL;
    BEGIN COMMENT;
    }

<INITIAL>PROCESSORS: {
    BEGIN ADD_PROCESSORS;
    }

<ADD_PROCESSORS>{integer} {
    BEGIN AWAIT_PROCESSOR_SEPARATOR;
    return graphloader::PROCESSOR_ID;
    }

<ADD_PROCESSORS>{comment} {
    pushed_state = ADD_PROCESSORS;
    BEGIN COMMENT;
    }

<AWAIT_PROCESSOR_SEPARATOR>{equals} {
    BEGIN AWAIT_PROCESSOR_NAME;
    }

<AWAIT_PROCESSOR_NAME>{string} {
    BEGIN ADD_PROCESSORS;
    return graphloader::PROCESSOR_NAME;
    }

<ADD_PROCESSORS>DEPENDENCIES: {
    BEGIN ADD_DEPENDENCIES;
    }

<ADD_DEPENDENCIES>{comment} {
    pushed_state = ADD_DEPENDENCIES;
    BEGIN COMMENT;
    }

<ADD_DEPENDENCIES>{integer} {
    BEGIN AWAIT_DEPENDENCY_SEPARATOR;
    return graphloader::DEP_DEST;
    }

<AWAIT_DEPENDENCY_SEPARATOR>{separator} {
    BEGIN AWAIT_DEPENDENCY_SLOT;
    }

<AWAIT_DEPENDENCY_SLOT>{integer} {
    BEGIN AWAIT_DEPENDENCY_LINK;
    return graphloader::DEP_SLOT;
    }

<AWAIT_DEPENDENCY_LINK>{link} {
    BEGIN AWAIT_DEPENDENCY_SOURCE;
    }

<AWAIT_DEPENDENCY_SOURCE>{integer} {
    BEGIN ADD_DEPENDENCIES;
    return graphloader::DEP_SOURCE;
    }

<ADD_DEPENDENCIES>PARAMETERS: {
    BEGIN SET_PARAMETERS;
    }

<SET_PARAMETERS>{comment} {
    pushed_state = SET_PARAMETERS;
    BEGIN COMMENT;
    }

<SET_PARAMETERS>{integer} {
    BEGIN AWAIT_PARAMETER_SEPARATOR;
    return graphloader::PARAM_DEST;
    }

<AWAIT_PARAMETER_SEPARATOR>{separator} {
    BEGIN AWAIT_PARAMETER_NAME;
    }

<AWAIT_PARAMETER_NAME>{string} {
    BEGIN AWAIT_PARAMETER_EQUALS;
    return graphloader::PARAM_NAME;
    }

<AWAIT_PARAMETER_EQUALS>{equals} {
    BEGIN AWAIT_PARAMETER_VALUE;
    }

<AWAIT_PARAMETER_VALUE>{chromaticity} {
    BEGIN SET_PARAMETERS;
    return graphloader::PARAM_VALUE_CHROMATICITY;
    }

<AWAIT_PARAMETER_VALUE>{float} {
    BEGIN SET_PARAMETERS;
    return graphloader::PARAM_VALUE_FLOAT;
    }

<AWAIT_PARAMETER_VALUE>{integer} {
    BEGIN SET_PARAMETERS;
    return graphloader::PARAM_VALUE_INT;
    }

<AWAIT_PARAMETER_VALUE>{true} {
    BEGIN SET_PARAMETERS;
    return graphloader::PARAM_VALUE_BOOL;
    }

<AWAIT_PARAMETER_VALUE>{false} {
    BEGIN SET_PARAMETERS;
    return graphloader::PARAM_VALUE_BOOL;
    }

<AWAIT_PARAMETER_VALUE>{string} {
    BEGIN SET_PARAMETERS;
    return graphloader::PARAM_VALUE_STRING;
    }

<SET_PARAMETERS>OUTPUT: {
    BEGIN AWAIT_OUTPUT;
    }
<AWAIT_OUTPUT>{integer} {
    return graphloader::OUTPUT_ID;
    }

%%